Arduino Coffeebots

Arduino Coffeebots by Judy Aime’ Castro, as seen in Make: Magazine issue #34

Contact:

teachers@teachmetomake.com

judyaime@gmail.com

This page can be reached at: bit.ly/coffeebot
Detailed construction steps can be found here

• Basic Coffeebot Schematic and Program
• Coffeebot with an LED
• Coffeebot with an Ultrasonic Distance Measuring Sensor
• Coffeebot with Text to Speech module
• Coffeebot Chassis Parts
• Coffeebot Electronics Parts List
• Tools

Basic CoffeeBot

Robot with two light sensors and two motors:

/*
This program makes your robot either seek light or avoid light, depending on how it is wired up.
Try this program first, and then start modifying it to give your robot the personality you desire.
Shine a flashlight, or hold your hand over a light sensor, to change the behaviour.
*/

void setup()
{
  // Set the mode of the digital pins to outputs to drive the motors
  // (the analog inputs are automatically inputs and so don’t need to be set)
  pinMode( 3, OUTPUT ); // motor
  pinMode( 5, OUTPUT ); // motor
}

void loop()
{
  // Compare the two light sensors
  if ( analogRead( 0 ) > analogRead( 2 )  ) // If one light sensor has more light than the other ...
  {
    digitalWrite( 3, LOW ); // turn this motor off ...
    digitalWrite( 5, HIGH ); // and this motor on to turn in one direction
  }

  if ( analogRead( 0 ) < analogRead( 2 )  ) // If the other
  {
    digitalWrite( 3, HIGH ); // turn this motor on
    digitalWrite( 5, LOW ); // and this motor off to turn in the other direction
  }

}

Add an LED

As an example of how to add things to your coffeebot, let’s attach an LED to pin 9.
Remember to use a resistor so that the LED doesn’t burn out:

And here is how we might use that LED in a program:

/*
This program makes your robot either seek light or avoid light, depending on how it is wired up.
Try this program first, and then start modifying it to give your robot the personality you desire.
Shine a flashlight, or hold your hand over a light sensor, to change the behaviour.

An LED is connected to pin 9; whenever the sensors measure unequal brightness this LED is turned on
*/
void setup()
{
  // Set the mode of the digital pins to outputs to drive the motors
  // (the analog inputs are automatically inputs and so don’t need to be set)
  pinMode( 3, OUTPUT ); // motor
  pinMode( 5, OUTPUT ); // motor
  pinMode( 9, OUTPUT ); // LED
}

void loop()
{
  // Compare the two light sensors
  if ( analogRead( 0 ) > analogRead( 2 )  ) // If one light sensor has more light than the other ...
  {
    digitalWrite( 3, LOW ); // turn this motor off ...
    digitalWrite( 5, HIGH ); // and this motor on to turn in one direction
    digitalWrite( 9, LOW ); // turn off the LED
  }

  if ( analogRead( 0 ) < analogRead( 2 )  ) // If the other
  {
    digitalWrite( 3, HIGH ); // turn this motor on
    digitalWrite( 5, LOW ); // and this motor off to turn in the other direction
    digitalWrite( 9, LOW ); // turn off the LED
  }

if ( analogRead( 0 ) == analogRead( 2 )  ) // If they read the same value
  {
    digitalWrite( 3, HIGH ); // turn this motor on
    digitalWrite( 5, HIGH ); // and this motor too, to go straight
    digitalWrite( 9, HIGH ); // turn on the LED
  }
}

Add an ultrasonic distance measuring sensor

The HC-SR04 is a popular ultrasonic distance measuring sensor. The sensor has two controlling pins: a trigger and an echo.  You can read more about it here. In this example we use the sensor to avoid obstacles in a very simple manner:

const int trigPin = 8;
const int echoPin = 7;
const int leftMotor = 5;
const int rightMotor = 6;

void setup() {
  pinMode(trigPin, OUTPUT);
  pinMode(echoPin, INPUT);
  pinMode(leftMotor, OUTPUT);
  pinMode(rightMotor, OUTPUT);

  digitalWrite(leftMotor, LOW); // Turn the motors off right away so it doesn't start moving
  digitalWrite(rightMotor, LOW);
}

void loop() {
  long duration, distance;

  // In order to measure a distance, we first send a trigger
  digitalWrite(trigPin, LOW);  
  delayMicroseconds(2);
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin, LOW);

  // After sending the trigger, wait for the echo
  duration = pulseIn(echoPin, HIGH);

  // The distance in CM is related to the time until the echo arrived
  distance = (duration/2) / 29.1;

  // Distances of more than 2M or less than zero might be an error; ignore them
  if ( (distance > 200) || (distance < 0))
  {
    digitalWrite(leftMotor, HIGH);
    digitalWrite(rightMotor, HIGH);
  }

  // If the nearest obstacle is closer than 1M away, turn
  else if  (distance < 100)
  {
    digitalWrite(leftMotor, LOW);
    digitalWrite(rightMotor, HIGH);
  }

  // once we've decided what to do, keep doing it for a little while
  delay(200);
}

Add a Text to Speech module and let your Coffeebot speak

Here is an example using the Emic 2 Text-To-Speech module from Parallax (also available at Spark Fun). The module is connected to Arduino digital outputs 2 and 3, and is programmed using the software serial library:

 /*
    Coffeebot using Emic 2 Text-to-Speech Module
*/

// include the SoftwareSerial library 
// so we can use it to talk to the Emic 2 module
#include <SoftwareSerial.h>

const int rxPin = 2;    // Serial input (connects to Emic 2 SOUT)
const int txPin = 3;    // Serial output (connects to Emic 2 SIN)

// set up a software serial port
SoftwareSerial emicSerial =  SoftwareSerial(rxPin, txPin);

void setup()  // Set up code called once on start-up
{
  // define pin modes
  pinMode(rxPin, INPUT);
  pinMode(txPin, OUTPUT);

  // set the data rate for the SoftwareSerial port
  emicSerial.begin(9600);

  /*
    When the Emic 2 powers on, it takes about 3 seconds for it to successfully
    initialize. It then sends a ":" character to indicate it's ready to accept
    commands. If the Emic 2 is already initialized, a CR will also cause it
    to send a ":"
  */
  emicSerial.print('\n');             // Send a CR in case the system is already up
  while (emicSerial.read() != ':');   // When the Emic 2 has initialized and is ready, it will send a single ':' character, so wait here until we receive it
  delay(10);                          // Short delay
  emicSerial.flush();                 // Flush the receive buffer
}

void loop()  // Main code, to run repeatedly
{
  // Speak some text
  emicSerial.print('S');
  emicSerial.print("Hello. This Coffeebot can talk!");  // Send the desired string to convert to speech
  emicSerial.print('\n');

  // Wait until the Emic 2 responds with a ":" 
  // indicating it's ready to accept the next command
  while (emicSerial.read() != ':');   

  // Since we are in loop(), this will speak repeatedly. Delay a bit between utterances.
  delay(5000);
}

Links that might be useful or interesting:

1. Really nice set of robot tutorials at Robotshop.
2. I really like mailing lists, and there are plenty on the subjects of robots. Two of my favorites are the Dallas Personal Robotics Group and the Portland Area Robotics Society

Parts List

Coffeebot Chassis Parts List

1. Coffee can or other suitable container for body
2. Craft sticks or other suitable materials for structural elements and decoration
3. Wine corks or other suitable items for front and back caster mounts
4. Water bottle caps or other suitable items for casters
5. Zip ties for attaching Arduino to chassis

Coffeebot Electronics Parts List

• N-chanel logic level MOSFET in TO-220 case, quantity: 2,e.g.:
  (Over-specifyingthis part makes construction easier and reduces chances of damage)
  12N10L Jameco Part no. 1071214
  IRLB 8721 Adafruit 355 or Oddwires ARK-0000007
  STP16NF06 RS Stock No. 486-2206 not logic level but can carry 8A at Vgs=5V so is fine
  STP36NF06 RS  Stock No. 486-2262 not logic level but can carry 15A at Vgs=5V so is fine
  IRLZ44 IRL540 BUZ11 IRL8113 IRL2203N IRLZ34N
  IRF530 not logic level but can carry 2A at Vgs=5V so is acceptable
• Gear motor and wheel, quantity: 2, e.g.:
  Solarbotics GM8 with GMPW wheel deal
  Similar motors available from many sources; search for “plastic robot gearmotor and wheel”
• LED (any type), quantity: 2, e.g.:
  Jameco Part no. 2152112
• Resistor for LED, 330 Ohm or so, quantity: 2, e.g.:
  Jameco Part no. 690742
• Photoresistor, most any type, quantity: 2, e.g.:
  Jameco Part no. 120299
  RS Stock No. 455-8036
  Oomlout
• Resistor for photoresistor quantity: 2
  Value should be roughly midway between photoresistor dark and light resistance values, e.g.:
  150K ohm  Jameco Part no. 691382 suitable for use with photoresistor Jameco Part no. 120299
  470K ohm RS Stock No. 707-7883 suitable for use with photoresistor RS Stock No. 455-8036
  However this varies a lot depending on ambient lighting conditions. A resistor selection is recommended to have on hand, such as the
  kit from Oomlout which has 25 resistors of all common values. This will also provide the resistors for the LEDs.
• Arduino Uno or Leonardo, or compatible
• Arduino headers e.g.:
  Oomlout Arduino Headers
• Battery holder with switch and coax power connector for Arduino, e.g.:
  Maker Shed MSBAT1
  Rapid Online Order Code 18-0296
  (Oomlout 9v Battery – Arduino Adapter  although it lacks a switch)
• 9 Volt Battery

Class Consumables Parts List

• Wire (all the different colors) e.g.:
  SK Pang e.g. Solid Core 22 AWG Black
  Cricklewood Electtonics Solid Core Hookup Wire Pack WP16
• Solder
• It is often cheaper to buy some parts such as LEDs, resistors, and photoresistors in bulk

Tools

Here are the basic tools that we find useful when constructing CoffeeBots:

1. A soldering iron. A fine tip is essential. Note the pencil size for comparison:

You can spend well over $100, but this particular model ($17 at Parts Express) is adequate.

2. Third hand:

This device has a pair of alligator clips on flexible arms. While not critical, it is extremely useful for holding things while you solder, for example holding the motor while you solder the wires to the motor terminals:

3. Hot melt glue gun:

4. Wire cutter, wire stripper, and needle nose pliers:

Most importantly, you want the wire cutters to have a small, fine tip, for cutting wires that are close to other wires:

That’s about it – it is useful to have other tools on hand but these are the only tools necessary